HELP! Passing Parameters using Properties...

You have several options. You could use the Form's Tag property: from Form1, set Form2.Tag = ProcessID, then read the value from Form2's code. Or, you could declare a Public variable in Form2 and set it from Form1:

Form2.VariableName = ProcessID

Or, you could define a custom property in Form2, but that seems like overkill in this case.

It looks like the .Tag property is not available until the form is fully loaded (that is, after the Form_Load event). You might try creating a Public Sub to do your WaitForSingleObject stuff; when you call the method, the form will load automatically.

Here's how I'd do it. Don't have Form2 (which I would call something like frmProgress or frmCancel) do anything except display the progress and notify the parent form if the user presses the Cancel button:

' frmCancel
Option Explicit
Public Event Cancel()

Private Sub cmdCancel_Click()
RaiseEvent Cancel
End Sub

Public Sub UpdateProgress(ByVal PercentDone As Integer)
' Update progress bar
End Sub

Have the main form do everything else: start the process, report progress to frmCancel, and abort the process if the user clicks Cancel:

' frmMain
Option Explicit
Private bCancel As Boolean
Private WithEvents CancelForm As frmCancel

Private Sub CancelForm_Cancel()
bCancel = True
End Sub

Private Sub Form_Click()

Dim I As Long

Set CancelForm = New frmCancel
CancelForm.Show

' Begin lengthy process
For I = 1 To 2000000000
' Every 1000th time through the loop...
If (I Mod 1000) = 0 Then
' Calculate percent complete and
' pass to CancelForm to update
' progress bar
CancelForm.UpdateProgress I / 20000000
' Check for Cancel event
DoEvents
' If cancelled, close CancelForm
' and abort process
If bCancel Then
Unload CancelForm
Exit For
End If
End If
Next

End Sub

But that's just me. ;-)

Thanks a lot for your help Phil - that worked a treat! I can now finally move on to the next part Of the Project! :D